; Undernet Secure Login Script for mIRC
; by SanitariuM @ #mIRCScripting

alias -l randnick { 
  return $rand(a,z) $+ $rand(a,z) $+ $rand(a,z) $+ $rand(a,z) $+ $rand(a,z) $+ $rand(a,z) $+ $rand(a,z) $+ $rand(a,z) 
}

alias xlogin { 
  .msg x@channels.undernet.org login USERNAME PASSWORD
  .timerxlogin 0 60 xlogin
}

on *:start:{ 
  nick $randnick 
}

on *:disconnect:{ 
  nick $randnick 
}

on *:connect:{ 
  mode $me +ix
  silence +*!*@*,~*!*@*undernet.org
  xlogin 
}

raw 396:*:{ 
  .timerxlogin off 
  set -u5 %connectnick 
  nick REGULARNICK
  .timerjoinchannels 1 10 joinchannels 
}

raw 433:*:{
  if (%connectnick) {
    nick ALTERNATENICK
  }
}

on *:nick:{
  if (%connectnick) {
    if ($me == $newnick) { 
      .timerjoinchannels off
      joinchannels
    }
  }
}

alias joinchannels { 
  ; The semicolon in front of a line disables it.  Remove the semicolon to enable the line.
  .join -n #chan1,#chan2,#chan3
  ; .msg x invite #chan1
  ; .msg x invite #chan2
  ; .join -n #keyedchan1 key_here
}

on *:invite:#:{
  if ($nick == x) {
    join -n $chan
  }
}